source: cpp/gdk/f0defxml.m4 @ 5

Last change on this file since 5 was 5, checked in by sz, 15 years ago

added the GDK (Genotype Development Kit)

File size: 1.1 KB
Line 
1divert(-1)
2
3define(`Invisible',1)
4define(`DontShowClass',`2')
5define(`AtFirstPart',`4')
6define(`AtSecondPart',`8')
7define(`InTheMiddle',`12')
8define(`MuscleClass',`16')
9define(`ReceptorClass',`32')
10define(`V1BendMuscle',`64')
11define(`V1RotMuscle',`128')
12
13define(`CLASS',`ifelse($4,NOXML,`divert(-1)',` <`CLASS' ID="$3" NAME="$1">')')
14define(`XPROP',ZPROP(X,$@))
15define(`PROP',ZPROP(-,$@))
16define(`ZPROP',
17`  <`PROP' ID="$2" ifelse($1,X,`XTRA="1" ')NAME="$5" `GROUP'="$3" FLAGS="$4" TYPE="$6" ifelse($7,,,MIN="$7" MAX="$8" DEF="$9" )/>')
18define(`GROUP',`  <`GROUP' NAME="$1" />')
19define(`ENDCLASS',` </`CLASS'>divert')
20
21define(`NEUROCLASS',` <`NEUROCLASS' ID="$2" NAME="$3" DESCRIPTION="$4" INPUTS="$5" OUTPUT="$6" LOCATION="$7" divert(2) >')
22define(`VISUALHINTS',`divert `VISUALHINTS'="eval($1)" divert(2)')
23define(`SYMBOL',`divert `SYMBOL'="$1" divert(2)')
24define(`NEUROPROP',`  <`NEUROPROP' ID="$1" NAME="$4" TYPE="$5" MIN="$6" MAX="$7" DEF="$8" />')
25define(`ENDNEUROCLASS',`divert`'undivert(2) </`NEUROCLASS'>')
26
27changecom
28divert<!DOCTYPE F0CLASSES>
29<F0CLASSES>
30divert(1)
31</F0CLASSES>
32divert
Note: See TracBrowser for help on using the repository browser.