source: cpp/frams/vm/framscript.l @ 473

Last change on this file since 473 was 468, checked in by Maciej Komosinski, 8 years ago

More sophisticated and accurate parsing of numbers

  • Property svn:eol-style set to native
File size: 4.8 KB
Line 
1%{
2// This file is a part of the Framsticks SDK.
3// Copyright (C) 2002-2015  Maciej Komosinski and Szymon Ulatowski.  See LICENSE.txt for details.
4// Refer to http://www.framsticks.com/ for further information.
5
6#include "framscript-defs.h"
7#include "framscript.tab.cpp.h"
8#include <math.h>
9
10#define YY_INPUT(buf,result,maxsize) {result=trctx.in->Vread(buf,1,maxsize);}
11#define YY_NEVER_INTERACTIVE 1
12
13static SString quoteMultiline(const SString &src);
14
15%}
16
17%option noyywrap
18%x asmcode
19%x asmcode2
20%x comment
21%x multiline
22
23%%
24
25[0-9]+\.[0-9]*                   |
26[0-9]+\.[0-9]*[eE][+-]?[0-9]+    |
27[0-9]+*[eE][+-]?[0-9]+           {if (framscriptlval.parseNumber(yytext,TDouble)==(yytext+yyleng)) return CONSTANT; else { trctx.err->printf("Invalid floating point number: '%s', ",SString(yytext,yyleng).c_str()); return INVALID_NUMBER;} }
28
29[0-9]+                |
300x[0-9a-fA-F]+        {if (framscriptlval.parseNumber(yytext,TInt)==(yytext+yyleng)) return CONSTANT; else { trctx.err->printf("Invalid integer: '%s', ",SString(yytext,yyleng).c_str()); return INVALID_NUMBER;} }
31
32"null"            {framscriptlval.setEmpty(); return CONSTANT;}
33\"([^\\\"]|\\.)*\" {framscriptlval.setString(SString(yytext+1,yyleng-2));return CONSTANT;}
34\"\"\"             {trctx.tmp=""; trctx.multilimit='\"'; BEGIN multiline;}
35"'''"              {trctx.tmp=""; trctx.multilimit='\''; BEGIN multiline;}
36"@line "[0-9]+\n   {trctx.line=atol(yytext+6);trctx.linechanged=true;}
37"@file "[^\n\t\r]+\n {trctx.srcname=SString(yytext+6,yyleng-7);trctx.namechanged=true;}
38
39[a-zA-Z_][a-zA-Z0-9_]* { int t=lookupToken(yytext);
40                         if (t>=0) return t;
41                         else
42                            {
43                            framscriptlval.setString(yytext);
44                            return framscriptIsObjectName(yytext)?OBJNAME:IDENT;
45                            }
46                       }
47"=="               return EQUAL;
48"<>"               return NOT_EQUAL;
49"!="               return NOT_EQUAL;
50">="               return GEQUAL;
51"<="               return LEQUAL;
52
53"+="                return ASSIGN_ADD;
54"-="                return ASSIGN_SUB;
55"*="                return ASSIGN_MUL;
56"/="                return ASSIGN_DIV;
57"%="                return ASSIGN_MOD;
58
59"++"                return PLUSPLUS;
60"--"                return MINUSMINUS;
61
62"&&"                return LOGIC_AND;
63"||"                return LOGIC_OR;
64
65"<<"                return LSHIFT;
66">>"                return RSHIFT;
67
68<INITIAL,asmcode,asmcode2>\/\/.*\n         {trctx.line++;trctx.linechanged=true;} // komentarz jednoliniowy
69<INITIAL,asmcode,asmcode2>\/\/[^\n]*       ;               // komentarz ale nie ma potem \n
70
71<INITIAL>\/\*       BEGIN comment;
72<comment>\n         {trctx.line++;trctx.linechanged=true;}
73<comment>\*\/       BEGIN 0;
74<comment>.          ;
75<multiline>.*       {
76                    char* end=strstr(yytext,trctx.multilimit=='\"' ? "\"\"\"" : "'''");
77                    if (end)
78                       {
79                       trctx.tmp+=string(yytext,end-yytext);
80                       framscriptlval.setString(quoteMultiline(SString(trctx.tmp.c_str())));
81                       yyless((end-yytext)+3);
82                       BEGIN 0;
83                       return CONSTANT;
84                       }
85                    else
86                       trctx.tmp+=string(yytext,yyleng);
87                    }
88<multiline>\n       {trctx.line++; trctx.linechanged=true; trctx.tmp+="\n";}
89[ \t\r\f]           ;
90\n                  {trctx.line++; trctx.linechanged=true;}
91.                   return (int)(unsigned char)yytext[0];
92
93"asm"[ \t\n\r]*"{"  {
94                    BEGIN asmcode;
95                    char *t=yytext;
96                    while(t=strchr(t+1,'\n')) trctx.line++;
97                    trctx.linechanged=true;
98                    return ASM;
99                    }
100<asmcode>.*\n {
101              char *t=yytext;
102              trctx.line++; trctx.linechanged=true;
103              while ((*t==' ')||(*t=='\t')) t++;
104              if (*t=='}') {yyless((t-yytext)+1); BEGIN 0; return '}';}
105              char *e=yytext+yyleng-1;
106              while (e[-1]=='\r') e--;
107              framscriptlval.setString(SString(t,e-t));
108              return ASMLINE;
109              }
110
111%%
112
113//exclusively for multiline, but it should not be needed, there is some unexpected difference between quoting \n and \" in framscript parsing (TODO)
114static SString quoteMultiline(const SString &src)
115{
116int len=src.len();
117SString ret((len*11)/10+10);
118const char*t=src.c_str();
119while(len>0)
120        {
121        switch(*t)
122            {
123            case '\"': ret+="\\\""; break;
124            case '\\': ret+="\\\\"; break;
125            default: ret+=*t;
126            }
127        t++; len--;
128        }
129return ret;
130}
131
132void framscript_init_lex()
133{
134BEGIN 0;
135yyrestart(0);
136}
137
138void framscript_cleanup_lex()
139{
140yy_delete_buffer(yy_current_buffer);
141}
Note: See TracBrowser for help on using the repository browser.